blob: a85ce87f404c8e76eba59e45457db632cf6abd32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit findlib toolchain-funcs
DESCRIPTION="OCaml interface to the Tcl/Tk GUI framework"
HOMEPAGE="https://garrigue.github.io/labltk/"
SRC_URI="https://github.com/garrigue/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="QPL-1.0 LGPL-2"
SLOT="0/${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
IUSE="+ocamlopt X"
RDEPEND="dev-lang/tk:=
>=dev-lang/ocaml-4.14:=[ocamlopt?,X(+)?]"
DEPEND="${RDEPEND}
dev-ml/findlib
"
PATCHES=(
"${FILESDIR}/findlib.patch"
"${FILESDIR}"/${PN}-8.06.9-configure-clang16.patch
"${FILESDIR}"/${P}-shuffle.patch
)
src_prepare() {
sed -i \
-e "s|ranlib|$(tc-getRANLIB)|" \
frx/Makefile \
|| die
default
}
src_configure() {
./configure --use-findlib --verbose $(usex X "--tk-x11" "--tk-no-x11") || die "configure failed!"
}
src_compile() {
emake -j1 all
use ocamlopt && emake -j1 opt
}
src_install() {
findlib_src_preinst
dodir /usr/bin
emake \
INSTALLDIR="${D}/$(ocamlc -where)/labltk" \
INSTALLBINDIR="${ED}/usr/bin/" \
install
dodoc Changes README.mlTk
}
|