blob: 0a9e59f88b3ada6d064ae901ded9ff3dd4157186 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_6} )
inherit distutils-r1
DESCRIPTION="database migrations tool, written by the author of SQLAlchemy"
HOMEPAGE="https://bitbucket.org/zzzeek/alembic"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="test doc"
RESTRICT="!test? ( test )"
# requires.txt cites 'SQLAlchemy>=0.7.3' which is really both old and silly
# because it shatters the testsuite. If 'someone' cares to adhere to correct form
# and edit to -0.7.3, feel free, and then pick up the pieces.
RDEPEND=">=dev-python/sqlalchemy-0.8.4[${PYTHON_USEDEP}]
dev-python/mako[${PYTHON_USEDEP}]
>=dev-python/python-editor-0.3[${PYTHON_USEDEP}]
dev-python/python-dateutil[${PYTHON_USEDEP}]"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
test? ( ${RDEPEND}
dev-python/nose[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}] )"
# For test phase
DISTUTILS_IN_SOURCE_BUILD=1
python_prepare_all() {
# suite passes all if run from source. The residual fail & error are quite erroneous
rm tests/test_script_consumption.py || die
distutils-r1_python_prepare_all
}
python_test() {
${EPYTHON} run_tests.py || die "Testing failed with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( docs/. )
distutils-r1_python_install_all
}
|