blob: 23334f649c637734a9205d822275c38d64cb4ea7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 optfeature pypi
DESCRIPTION="Python library for arbitrary-precision floating-point arithmetic"
HOMEPAGE="
https://mpmath.org/
https://github.com/mpmath/mpmath/
https://pypi.org/project/mpmath/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-python/hypothesis[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/gmpy2[${PYTHON_USEDEP}]
' 'python3*')
!mips? (
dev-python/ipython[${PYTHON_USEDEP}]
!hppa? (
dev-python/matplotlib[${PYTHON_USEDEP}]
)
)
)
"
EPYTEST_XDIST=1
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=()
case ${EPYTHON} in
pypy3)
EPYTEST_DESELECT+=(
# minor whitespace mismatch, apparently fixed in pypy 7.3.18
mpmath/tests/test_format.py::test_mpf_floats_bulk
mpmath/tests/test_format.py::test_mpc_complexes
)
;;
esac
# CLI crashes otherwise, sigh (not a regression)
# https://github.com/mpmath/mpmath/issues/907
> "${HOME}/.python_history" || die
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p rerunfailures --reruns=5 -p timeout
}
pkg_postinst() {
optfeature "gmp support" dev-python/gmpy2
optfeature "matplotlib support" dev-python/matplotlib
}
|
