blob: bdd79e4a4d3be5acae723611aa0a49abb7b6a02e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( pypy3 python3_{10..12} )
inherit distutils-r1 pypi
DESCRIPTION="Mock out responses from the requests package"
HOMEPAGE="
https://github.com/jamielennox/requests-mock/
https://pypi.org/project/requests-mock/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm arm64 ppc64 ~riscv x86"
RDEPEND="
>=dev-python/requests-2.3[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/pbr-0.8[${PYTHON_USEDEP}]
test? (
dev-python/fixtures[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/requests-futures[${PYTHON_USEDEP}]
dev-python/testtools[${PYTHON_USEDEP}]
)
"
distutils_enable_sphinx doc/source
distutils_enable_tests pytest
python_prepare_all() {
# Disable reno which only works inside a git repository
sed -i "s/'reno.sphinxext',//" doc/source/conf.py || die
# Remove the release notes section which requires reno
rm doc/source/release-notes.rst || die
sed -i '/^=============$/,/release-notes/d' doc/source/index.rst || die
# Disable a test which requires purl (not in the tree)
sed -e "/^import purl$/d" -e "s/test_with_purl/_&/" \
-i tests/test_adapter.py || die
distutils-r1_python_prepare_all
}
|