blob: 5374e0aaaa63c3f2fe2b8963479700d0d3b95d24 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GUILE_COMPAT=( 2-2 3-0 )
inherit guile autotools
DESCRIPTION="Simple framework for building readers for GNU Guile"
HOMEPAGE="https://www.nongnu.org/guile-reader/"
SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="${GUILE_REQUIRED_USE}"
RDEPEND="${GUILE_DEPS}"
DEPEND="${RDEPEND}"
BDEPEND="dev-util/gperf"
PATCHES=(
"${FILESDIR}/${PN}-0.6.3-implicit-fn-decl.patch"
"${FILESDIR}/${PN}-0.6.3-slot.patch"
)
src_prepare() {
default
eautoreconf
guile_bump_sources
}
configure_one_src() {
local -x guile_snarf="${GUILESNARF}"
# We don't have lightning packaged and, naturally, guile-reader has
# no --with-... for it. Suppress the automagic.
econf \
ac_cv_header_lightning_h=no
}
src_configure() {
guile_foreach_impl configure_one_src
}
compile_one_src() {
# Makefile appears to be missing seemingly all dependencies.
emake -j1 --shuffle=none
}
src_compile() {
guile_foreach_impl compile_one_src
}
src_install() {
guile_src_install
find "${ED}" -type f -name '*.la' -delete || die
}
|
