blob: 9859bfa53a9e301217aa142cc7ba0e892b3cdd8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
HOMEPAGE="https://gitlab.freedesktop.org/wlroots/wlroots"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://gitlab.freedesktop.org/${PN}/${PN}.git"
inherit git-r3
SLOT="0/9999"
else
SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/releases/${PV}/downloads/${P}.tar.gz -> ${P}.gl.tar.gz"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
SLOT="0/$(ver_cut 2)"
fi
LICENSE="MIT"
IUSE="+drm +libinput tinywl vulkan x11-backend xcb-errors X"
REQUIRED_USE="
xcb-errors? ( || ( x11-backend X ) )
"
DEPEND="
>=dev-libs/wayland-1.21.0
media-libs/mesa[egl(+),gles2]
sys-auth/seatd:=
virtual/libudev
>=x11-libs/libdrm-2.4.114
x11-libs/libxkbcommon
>=x11-libs/pixman-0.42.0
drm? ( sys-apps/hwdata )
libinput? ( >=dev-libs/libinput-1.14.0:= )
vulkan? (
dev-util/glslang:=
dev-util/vulkan-headers
media-libs/vulkan-loader
)
xcb-errors? ( x11-libs/xcb-util-errors )
x11-backend? (
x11-libs/libxcb:=
x11-libs/xcb-util-renderutil
)
X? (
x11-base/xwayland
x11-libs/libxcb:=
x11-libs/xcb-util-wm
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
>=dev-libs/wayland-protocols-1.28
dev-util/wayland-scanner
virtual/pkgconfig
"
src_configure() {
local backends=(
$(usev drm)
$(usev libinput)
$(usev x11-backend 'x11')
)
local meson_backends=$(IFS=','; echo "${backends[*]}")
local emesonargs=(
$(meson_feature xcb-errors)
$(meson_use tinywl examples)
-Drenderers=$(usex vulkan 'gles2,vulkan' gles2)
$(meson_feature X xwayland)
-Dbackends=${meson_backends}
)
meson_src_configure
}
src_install() {
meson_src_install
dodoc docs/*
if use tinywl; then
dobin "${BUILD_DIR}"/tinywl/tinywl
fi
}
pkg_postinst() {
elog "You must be in the input group to allow your compositor"
elog "to access input devices via libinput."
}
|