blob: 238b58935f3c9673147c9f6a0b42453addbf0028 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop autotools
MY_P=GStreamripperX-${PV}
DESCRIPTION="A GTK+ toolkit based frontend for streamripper"
HOMEPAGE="https://sourceforge.net/projects/gstreamripper/"
SRC_URI="https://downloads.sourceforge.net/gstreamripper/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 sparc x86"
RDEPEND="
x11-libs/gtk+:2
media-sound/streamripper"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}/${P}-C99-fixes.patch"
"${FILESDIR}/${P}-C23-fixes.patch"
)
src_prepare() {
default
# bug https://bugs.gentoo.org/879711
eautoreconf
}
src_compile() {
emake CFLAGS="${CFLAGS}"
}
src_install() {
local docdir="${EPREFIX}/usr/share/doc/${PF}"
emake \
DESTDIR="${D}" \
gstreamripperxdocdir="${docdir}" \
install
einstalldocs
rm "${ED}"/${docdir}/COPYING || die
make_desktop_entry gstreamripperx GStreamripperX
}
|
