blob: 41b0233119b4e521b9b5b94f4c33f56623a3f60a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE="xml(+)"
inherit gnome.org gnome2-utils python-single-r1 meson virtualx xdg
DESCRIPTION="Music management and playback software for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Rhythmbox"
LICENSE="GPL-2"
SLOT="0"
IUSE="cdr daap dbus keyring gtk-doc ipod libnotify lirc mtp +python test +udev upnp-av"
RESTRICT="!test? ( test )"
REQUIRED_USE="
ipod? ( udev )
mtp? ( udev )
dbus? ( python )
python? ( ${PYTHON_REQUIRED_USE} )
"
KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
DEPEND="
x11-libs/cairo
>=x11-libs/gdk-pixbuf-2.18:2
>=dev-libs/glib-2.66.0:2
>=dev-libs/gobject-introspection-0.10:=
>=media-libs/gstreamer-1.4.0:1.0[introspection]
>=media-libs/gst-plugins-base-1.4.0:1.0[introspection]
>=x11-libs/gtk+-3.20.0:3[introspection]
dev-libs/json-glib
>=dev-libs/libpeas-0.7.3:0[gtk]
>=net-libs/libsoup-3.0.7:3.0
>=dev-libs/libxml2-2.7.8:2
x11-libs/pango
>=sys-libs/tdb-1.2.6
>=dev-libs/totem-pl-parser-3.2:=
cdr? ( >=app-cdr/brasero-2.91.90 )
daap? (
>=net-libs/libdmapsharing-3.9.11:4.0=
>=media-plugins/gst-plugins-soup-1.4:1.0
)
keyring? ( >=app-crypt/libsecret-0.18 )
libnotify? ( >=x11-libs/libnotify-0.7.0 )
lirc? ( app-misc/lirc )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
')
)
udev? (
dev-libs/libgudev:=
ipod? ( >=media-libs/libgpod-0.7.92[udev] )
mtp? ( >=media-libs/libmtp-0.3 )
)
"
RDEPEND="${DEPEND}
media-plugins/gst-plugins-soup:1.0
|| (
media-plugins/gst-plugins-cdparanoia:1.0
media-plugins/gst-plugins-cdio:1.0
)
media-plugins/gst-plugins-meta:1.0
media-plugins/gst-plugins-taglib:1.0
x11-themes/adwaita-icon-theme
python? (
>=dev-libs/libpeas-0.7.3:0[python,${PYTHON_SINGLE_USEDEP}]
net-libs/libsoup:3.0[introspection]
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
dbus? ( sys-apps/dbus )
keyring? ( >=app-crypt/libsecret-0.18[introspection] )
)
upnp-av? (
>=media-libs/grilo-0.3.15-r1:0.3
>=media-plugins/grilo-plugins-0.3.16:0.3[upnp-av]
)
"
BDEPEND="
gtk-doc? ( dev-util/gtk-doc )
dev-util/itstool
virtual/pkgconfig
test? ( dev-libs/check )
"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local emesonargs=(
$(meson_feature cdr brasero)
$(meson_feature daap)
-Dfm_radio=enabled
$(meson_feature upnp-av grilo)
$(meson_feature udev gudev)
$(meson_feature ipod)
$(meson_feature libnotify)
$(meson_feature keyring libsecret)
$(meson_feature lirc)
$(meson_feature mtp)
$(meson_feature python plugins_python)
-Dplugins_vala=disabled
-Dsample-plugins=false
-Dhelp=true
$(meson_use gtk-doc gtk_doc)
$(meson_feature test tests)
)
meson_src_configure
}
src_test() {
unset SESSION_MANAGER
"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
GSETTINGS_SCHEMA_DIR="${S}/data" virtx meson_src_test
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
