blob: 3df344d4160185944d27f748a3de0dfdef51472c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Utilities for editing and replaying previously captured network traffic"
HOMEPAGE="http://tcpreplay.appneta.com/ https://github.com/appneta/tcpreplay"
SRC_URI="https://github.com/appneta/${PN}/releases/download/v${PV}/${P}.tar.xz"
S="${WORKDIR}"/${P/_/-}
LICENSE="BSD GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm ~sparc x86"
IUSE="debug pcapnav +tcpdump"
# libpcapnav for pcapnav-config
BDEPEND="
net-libs/libpcapnav
>=sys-devel/autogen-5.18.4[libopts]
"
DEPEND="
dev-libs/libdnet
>=net-libs/libpcap-0.9
pcapnav? ( net-libs/libpcapnav )
tcpdump? ( net-analyzer/tcpdump )
"
RDEPEND="${DEPEND}"
DOCS=( docs/{CHANGELOG,CREDIT,HACKING,TODO} )
PATCHES=(
"${FILESDIR}"/${PN}-4.3.0-enable-pcap_findalldevs.patch
)
src_prepare() {
default
sed -i \
-e 's|#include <dnet.h>|#include <dnet/eth.h>|g' \
src/common/sendpacket.c || die
sed -i \
-e 's|@\([A-Z_]*\)@|$(\1)|g' \
-e '/tcpliveplay_CFLAGS/s|$| $(LDNETINC)|g' \
-e '/tcpliveplay_LDADD/s|$| $(LDNETLIB)|g' \
src/Makefile.am || die
eautoreconf
}
src_configure() {
# By default it uses static linking. Avoid that, bug 252940
econf \
$(use_enable debug) \
$(use_with pcapnav pcapnav-config "${BROOT}"/usr/bin/pcapnav-config) \
$(use_with tcpdump tcpdump "${ESYSROOT}"/usr/sbin/tcpdump) \
--enable-dynamic-link \
--enable-local-libopts \
--enable-shared \
--with-libdnet \
--with-testnic2=lo \
--with-testnic=lo
}
src_test() {
if [[ ! ${EUID} -eq 0 ]]; then
ewarn "Some tests were disabled due to FEATURES=userpriv"
ewarn "To run all tests issue the following command as root:"
ewarn " # make -C ${S}/test"
emake -j1 -C test tcpprep
else
emake -j1 test || {
ewarn "Note that some tests require eth0 iface to be up." ;
die "self test failed - see ${S}/test/test.log" ; }
fi
}
|