blob: aa97d1c68ceeb68b46a8497ffaca931868f13640 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit linux-info qmake-utils systemd
DESCRIPTION="A multicast proxy for IGMP/MLD"
HOMEPAGE="https://mcproxy.realmv6.org/ https://github.com/mcproxy/mcproxy"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${P}/${PN}"
KEYWORDS="amd64 x86"
LICENSE="GPL-2+"
SLOT="0"
IUSE="doc"
DEPEND="
dev-qt/qtcore:5
doc? ( app-text/doxygen )
"
PATCHES=(
"${FILESDIR}/${P}-clang.patch"
"${FILESDIR}/${P}-fix-checksum-calculation.patch"
)
CONFIG_CHECK="~IP_MULTICAST ~IP_MROUTE"
src_prepare() {
# Change install path from '/usr/local/bin' to '/usr/bin'
sed -e 's/local//' -i mcproxy.pro || die
default
}
src_configure() {
eqmake5
}
src_compile() {
default
use doc && emake doc
}
src_install() {
emake INSTALL_ROOT="${ED}" install
insinto /etc
doins mcproxy.conf
newinitd "${FILESDIR}"/mcproxy.initd mcproxy
systemd_dounit "${FILESDIR}"/mcproxy.service
newconfd "${FILESDIR}"/mcproxy.confd mcproxy
use doc && dodoc -r ../docs/.
}
|
