blob: 3471a1f73bd58fb9ee763045718166bf0aa868cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
JAVA_PKG_OPT_USE=client
inherit cmake desktop java-pkg-opt-2 verify-sig
DESCRIPTION="A fast replacement for TigerVNC"
HOMEPAGE="https://www.turbovnc.org/"
SRC_URI="
https://sourceforge.net/projects/turbovnc/files/${PV}/${P}.tar.gz/download -> ${P}.tar.gz
verify-sig? ( https://sourceforge.net/projects/turbovnc/files/${PV}/${P}.tar.gz.sig/download -> ${P}.tar.gz.sig )
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+server +ssl"
REQUIRED_USE="|| ( client server )"
COMMON_DEPEND="
x11-apps/xauth
x11-libs/libX11
x11-libs/libXext
x11-misc/xkeyboard-config
client? (
media-libs/libjpeg-turbo:=[java]
x11-libs/libXi
!net-misc/tigervnc
)
server? (
media-libs/libjpeg-turbo:=
sys-libs/pam
sys-libs/zlib
virtual/opengl
x11-libs/libXau
x11-libs/libXdmcp
x11-libs/libXfont2
x11-libs/pixman
ssl? ( dev-libs/openssl:= )
!net-misc/tigervnc[server]
)
"
RDEPEND="
${COMMON_DEPEND}
x11-apps/xkbcomp
client? ( >=virtual/jre-1.8:* )
"
# libbz2.so.1, libfontenc.so.1 and libfreetype.so.6 are used by libXfont2.so.2
# but cmake will look for them, so add them here
DEPEND="
${COMMON_DEPEND}
x11-libs/xtrans
client? ( >=virtual/jdk-1.8:* )
server? (
app-arch/bzip2
media-libs/freetype
x11-libs/libfontenc
)
"
BDEPEND="
verify-sig? ( sec-keys/openpgp-keys-vgl-turbovnc )
"
PATCHES=( "${FILESDIR}"/"${PN}"-3.0-fix-musl-compilation.patch )
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/vgl-turbovnc.asc
pkg_pretend() {
if use ssl && ! use server; then
einfo "USE=\"ssl\" selected but USE=\"server\" is not. The SSL support is unused"
fi
}
src_prepare() {
use client && java-pkg-opt-2_src_prepare
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DTVNC_BUILDVIEWER=$(usex client)
-DTVNC_BUILDHELPER=$(usex client)
-DTVNC_BUILDSERVER=$(usex server)
-DTVNC_BUILDWEBSERVER=$(usex server)
)
if use server ; then
mycmakeargs+=(
-DTVNC_SYSTEMLIBS=ON
-DTVNC_SYSTEMX11=ON
-DXKB_BIN_DIRECTORY=/usr/bin
-DXKB_DFLT_RULES=base
)
if use ssl ; then
# Link properly against OpenSSL to ensure
# we catch e.g. ABI change
# (i.e. don't dlopen it)
mycmakeargs+=(
-DTVNC_USETLS=OpenSSL
-DTVNC_DLOPENSSL=OFF
)
else
mycmakeargs+=( -DTVNC_USETLS=OFF )
fi
fi
if use client ; then
export JAVACFLAGS="$(java-pkg_javac-args)"
export JNI_CFLAGS="$(java-pkg_get-jni-cflags)"
fi
cmake_src_configure
}
src_install() {
cmake_src_install
if use client ; then
java-pkg_dojar "${BUILD_DIR}"/java/VncViewer.jar
make_desktop_entry vncviewer "TurboVNC Viewer" /usr/share/icons/hicolor/48x48/apps/${PN}.png
fi
# Don't install incompatible init script
rm -rf "${ED}"/etc/init.d/ || die
rm -rf "${ED}"/etc/sysconfig/ || die
# Conflicts with x11-base/xorg-server
find "${ED}"/usr/share/man/man1/ -name Xserver.1\* -delete || die
einstalldocs
}
|
