blob: 5829c9167987e08c4d9ab24ef1e85736336f7167 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ROCM_VERSION=${PV}
inherit cmake rocm
DESCRIPTION="HIP parallel primitives for developing performant GPU-accelerated code on ROCm"
HOMEPAGE="https://github.com/ROCm/rocPRIM"
SRC_URI="https://github.com/ROCm/rocPRIM/archive/rocm-${PV}.tar.gz -> rocPRIM-${PV}.tar.gz"
S="${WORKDIR}/rocPRIM-rocm-${PV}"
LICENSE="MIT"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~amd64"
IUSE="benchmark test"
REQUIRED_USE="
benchmark? ( ${ROCM_REQUIRED_USE} )
test? ( ${ROCM_REQUIRED_USE} )
"
RDEPEND="dev-util/hip
benchmark? ( dev-cpp/benchmark )
test? ( dev-cpp/gtest )"
BDEPEND="dev-build/rocm-cmake
>=dev-build/cmake-3.22"
DEPEND="${RDEPEND}"
RESTRICT="!test? ( test )"
PATCHES=( "${FILESDIR}"/${PN}-5.7.1-expand-isa-compatibility.patch )
src_prepare() {
# install benchmark files
if use benchmark; then
sed -e "/get_filename_component/s,\${BENCHMARK_SOURCE},${PN}_\${BENCHMARK_SOURCE}," \
-e "/add_executable/a\ install(TARGETS \${BENCHMARK_TARGET})" -i benchmark/CMakeLists.txt || die
fi
cmake_src_prepare
}
src_configure() {
rocm_use_hipcc
local mycmakeargs=(
-DCMAKE_SKIP_RPATH=ON
-DAMDGPU_TARGETS="$(get_amdgpu_flags)"
-DBUILD_TEST=$(usex test ON OFF)
-DBUILD_BENCHMARK=$(usex benchmark ON OFF)
-DBUILD_FILE_REORG_BACKWARD_COMPATIBILITY=OFF
-DROCM_SYMLINK_LIBS=OFF
)
cmake_src_configure
}
src_test() {
check_amdgpu
# uses HMM to fit tests to default <512M iGPU VRAM
ROCPRIM_USE_HMM="1" cmake_src_test -j1
}
|
