blob: 86cc15f7cf1ebb3c5fff79af84d601a0acf64c8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit linux-info systemd
DESCRIPTION="Daemon for Advanced Configuration and Power Interface"
HOMEPAGE="https://sourceforge.net/projects/acpid2/"
SRC_URI="https://downloads.sourceforge.net/${PN}2/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~loong ~riscv x86"
IUSE="selinux"
RDEPEND="selinux? ( sec-policy/selinux-apm )"
DEPEND=">=sys-kernel/linux-headers-3"
PATCHES=(
"${FILESDIR}"/${PN}-2.0.34-lfs.patch
)
pkg_pretend() {
local CONFIG_CHECK="~INPUT_EVDEV"
local WARNING_INPUT_EVDEV="CONFIG_INPUT_EVDEV is required for ACPI button event support."
[[ ${MERGE_TYPE} != buildonly ]] && check_extra_config
}
pkg_setup() { :; }
src_install() {
emake DESTDIR="${D}" install
newdoc kacpimon/README README.kacpimon
dodoc -r samples
rm -f "${D}"/usr/share/doc/${PF}/COPYING || die
exeinto /etc/acpi
newexe "${FILESDIR}"/${PN}-1.0.6-default.sh default.sh
exeinto /etc/acpi/actions
newexe samples/powerbtn/powerbtn.sh powerbtn.sh
insinto /etc/acpi/events
newins "${FILESDIR}"/${PN}-1.0.4-default default
newinitd "${FILESDIR}"/${PN}-2.0.26-init.d ${PN}
newconfd "${FILESDIR}"/${PN}-2.0.16-conf.d ${PN}
systemd_dounit "${FILESDIR}"/${PN}.{service,socket}
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog
elog "You may wish to read the Gentoo Linux Power Management Guide,"
elog "which can be found online at:"
elog "https://wiki.gentoo.org/wiki/Power_management/Guide"
elog
fi
}
|
