blob: bb69a6b70dcc97bdcd6e543347cde07b27baf929 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="GUI frontend to xmodmap"
HOMEPAGE="https://packages.qa.debian.org/x/xkeycaps.html"
SRC_URI="
mirror://debian/pool/main/x/${PN}/${PN}_${PV/_p*}.orig.tar.gz
mirror://debian/pool/main/x/${PN}/${PN}_${PV/_p/-}.debian.tar.xz
"
S=${WORKDIR}/${P/_p*}
LICENSE="HPND"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
RDEPEND="
x11-libs/libX11
x11-libs/libXaw
x11-libs/libXext
x11-libs/libXmu
x11-libs/libXt
x11-misc/xbitmaps
"
DEPEND="
${RDEPEND}
x11-base/xorg-proto
"
BDEPEND="
sys-devel/gcc
>=x11-misc/imake-1.0.8-r1
"
DOCS=( README defining.txt hierarchy.txt sgi-microsoft.txt )
PATCHES=(
"${FILESDIR}"/${P/_p*}-Imakefile.patch
"${FILESDIR}"/${P}-clang16.patch
)
src_prepare() {
eapply $(
for file in $(cat "${WORKDIR}"/debian/patches/series)
do echo "${WORKDIR}"/debian/patches/${file}
done
)
default
}
src_configure() {
CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" \
IMAKECPP="${IMAKECPP:-${CHOST}-gcc -E}" xmkmf || die
sed -i \
-e "s,all:: xkeycaps.\$(MANSUFFIX).html,all:: ,g" \
Makefile || die
}
src_compile() {
emake \
CC="$(tc-getCC)" \
CDEBUGFLAGS="${CFLAGS}"
}
src_install() {
default
newman ${PN}.man ${PN}.1
}
|
