media-video/flowblade : drop package ; media-video/shotcut : new package

2 files changed, 79 insertions, 0 deletions

diff --git a/media-video/shotcut/Manifest b/media-video/shotcut/Manifest
new file mode 100644
index 00000000..7468f4ba
--- /dev/null
+++ b/media-video/shotcut/Manifest
@@ -0,0 +1 @@
+DIST shotcut-17.12.tar.gz 4021714 SHA256 15c0e435e61fead1042311fef5d86f3bfd5297044fd4c8e04b432a2ce340503c SHA512 4598ebbfbae8ffebe65b07d7b1476dc81d24689e571bf4a044658deb569b6949be5275cdd2f1edde8012b7cadb3386a80f1a6f7f2b6a2ad2ed7693a3becaf823 WHIRLPOOL 3f14503b15d91f1746ead13e112d16edb6bafd1c41b044729dba3c58615c2be6eddbad821535d249e35903eafa78c333d6f29de2cd272d16c08dace36544a3ca
diff --git a/media-video/shotcut/shotcut-17.12.ebuild b/media-video/shotcut/shotcut-17.12.ebuild
new file mode 100644
index 00000000..cb4652fa
--- /dev/null
+++ b/media-video/shotcut/shotcut-17.12.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="ca cs da de el en es fr gd hu it ja nb ne nl oc pl pt_BR pt_PT ru sk sl tr uk zh_CN zh_TW"
+
+inherit l10n qmake-utils versionator
+
+DESCRIPTION="A free, open source, cross-platform video editor"
+HOMEPAGE="https://www.shotcut.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mltframework/${PN}.git"
+	KEYWORDS=""
+else
+	MY_PV=$(replace_version_separator 2 '-')
+	MY_P=${PN}-${MY_PV}
+
+	SRC_URI="https://github.com/mltframework/${PN}/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/ladspa-sdk
+	media-libs/libsdl:0
+	media-libs/libvpx
+	media-libs/mlt[ffmpeg,frei0r,qt5,sdl,xml]
+	media-libs/x264
+	media-plugins/frei0r-plugins
+	media-sound/lame
+	media-video/ffmpeg
+	virtual/jack
+"
+
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md )
+
+src_prepare() {
+	local tsdir="${S}/translations"
+	local mylrelease="$(qt5_get_bindir)"/lrelease
+
+	prepare_locale() {
+		"${mylrelease}" "${tsdir}/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	l10n_find_plocales_changes "${tsdir}" "${PN}_" '.ts'
+	l10n_for_each_locale_do prepare_locale
+
+	default
+}
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}"/usr
+}
+
+src_install() {
+	newicon "${S}/icons/shotcut-logo-64.png" "${PN}.png"
+	make_desktop_entry shotcut "Shotcut"
+	emake INSTALL_ROOT="${D}" install
+}