sys-boot/plymouth : adjust deps

1 files changed, 0 insertions, 101 deletions

diff --git a/sys-boot/plymouth/plymouth-0.9.4-r10.ebuild b/sys-boot/plymouth/plymouth-0.9.4-r10.ebuild
deleted file mode 100644
index c768739d..00000000
--- a/sys-boot/plymouth/plymouth-0.9.4-r10.ebuild
+++ /dev/null
@@ -1,101 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit flag-o-matic
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/plymouth"
-else
-	SRC_URI="https://www.freedesktop.org/software/plymouth/releases/${P}.tar.xz"
-	KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
-fi
-
-inherit autotools readme.gentoo-r1 toolchain-funcs
-
-DESCRIPTION="Graphical boot animation (splash) and logger"
-HOMEPAGE="https://cgit.freedesktop.org/plymouth/"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="debug gdm +gtk +libkms +pango +split-usr static-libs +udev"
-
-CDEPEND="
-	>=media-libs/libpng-1.2.16:=
-	gtk? (
-		dev-libs/glib:2
-		>=x11-libs/gtk+-3.14:3
-		x11-libs/cairo
-	)
-	libkms? ( x11-libs/libdrm[libkms] )
-	pango? ( >=x11-libs/pango-1.21 )
-"
-DEPEND="${CDEPEND}
-	elibc_musl? ( sys-libs/rpmatch-standalone )
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	virtual/pkgconfig
-"
-# Block due bug #383067
-RDEPEND="${CDEPEND}
-	udev? ( virtual/udev )
-	!<sys-kernel/dracut-0.37-r3
-"
-
-DOC_CONTENTS="
-	Follow the following instructions to set up Plymouth:\n
-	https://wiki.gentoo.org/wiki/Plymouth#Configuration
-"
-
-PATCHES=(
-	"${FILESDIR}"/0.9.3-glibc-sysmacros.patch
-	"${FILESDIR}"/"${PN}"-default-theme.patch
-)
-
-src_prepare() {
-	use elibc_musl && append-ldflags -lrpmatch
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local myconf=(
-		--with-system-root-install=no
-		--localstatedir=/var
-		--without-rhgb-compat-link
-		--enable-documentation
-		--disable-systemd-integration
-		$(use_enable !static-libs shared)
-		$(use_enable static-libs static)
-		$(use_enable debug tracing)
-		$(use_enable gtk gtk)
-		$(use_enable libkms drm)
-		$(use_enable pango)
-		$(use_enable gdm gdm-transition)
-		$(use_with udev)
-	)
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	default
-
-	# Provided by redcore-artwork-core
-	rm "${D}/usr/share/plymouth/bizcom.png"
-
-	if use split-usr ; then
-		# Install compatibility symlinks as some rdeps hardcode the paths
-		dosym ../usr/bin/plymouth /bin/plymouth
-		dosym ../usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
-		dosym ../usr/sbin/plymouthd /sbin/plymouthd
-	fi
-
-	readme.gentoo_create_doc
-
-	# looks like make install create /var/run/plymouth
-	# this is not needed for systemd, same should hold for openrc
-	# so remove
-	rm -rf "${D}"/var/run
-}